H DATEDIT(*YMD)                                                                                  
     FQAFDACCP  IP   E             DISK                                                               
     FOUTFIL    O  A F  112        DISK                                                               
     ‚*---------------------------------------------------------------------                          
     ‚* Stand Alone Fields - TOP                                                                      
     ‚*---------------------------------------------------------------------                          
     D #ON             S              1                                                               
     D ACCPTH          S             20                                                               
     D AS2RSK          S             72                                                               
     D FIELD           S              6                                                               
     D MAINT           S             10                                                               
     D ORD#            S              6                                                               
     ‚*---------------------------------------------------------------------                          
     ‚* Stand Alone Fields - BOTTOM                                                                   
     ‚*---------------------------------------------------------------------                          
     C     *ENTRY        PLIST                                                                        
     C                   PARM                    ORD#                                                 
     C                   IF        #ON <> *ON                                                         
     C                   MOVEL     *ALL'*'       AS2RSK                                               
     C                   EXCEPT    ASS2RS                                                             
     C                   SELECT                                                                       
     C                   WHEN      APMANT = 'I'                                                       
     C                   MOVEL     'Immed'       MAINT                                                
     C                   WHEN      APMANT = 'R'                                                       
     C                   MOVEL     'Rebuild'     MAINT                                                
     C                   WHEN      APMANT = 'D'                                                       
     C                   MOVEL     'Delayed'     MAINT                                                
     C                   ENDSL                                                                        
     C                   IF        APUNIQ = 'Y'                                                       
     C     'Unique'      CAT       'Key':1       ACCPTH                                               
     C                   ELSE                                                                         
     C     'Non-Uniq'    CAT       'ue Key':0    ACCPTH                                               
     C                   ENDIF                                                                        
     C                   EXCEPT    TYPE                                                               
     C                   IF        APFILA <> '*PHY'                                                   
     C                   EXCEPT    BASED                                                              
     C                   ENDIF                                                                        
     C                   EXCEPT    HEADER                                                             
     C                   MOVEL     *ON           #ON                                                  
     C                   ENDIF                                                                        
     ‚*                                                                                               
     C                   MOVEL     APKEYF        FIELD                                                
     C                   IF        APKSEQ = 'D'                                                       
     C                   MOVEL     *ON           *IN18                                                
     C                   ELSE                                                                         
     C                   MOVEL     *OFF          *IN18                                                
     C                   ENDIF                                                                        
     ‚*                                                                                               
     C                   EXCEPT    DETAIL                                                             
     CLR                 IF        APSELO = 'Y'                                                       
     CLR                 EXCEPT    WARN                                                               
     CLR                 ENDIF                                                                        
     CLR                 MOVEL     *ON           *INLR                                                
     OOUTFIL    EADD         HEADER                                                                   
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                                         +  1 'Key for file'                                    
     O                       APFILE            +  1                                                   
     O          EADD         HEADER                                                                   
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           18 'C'                                               
     O                                           25 'ky'                                              
     O                       APFILE              35                                                   
     O                                           42 'Klist'                                           
     O          EADD         DETAIL                                                                   
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           18 'C'                                               
     O                                           42 'KFLD '                                           
     O                       APKEYF              72                                                   
     O               18                         112 'Descending          '                            
     O              N18                         112 'Ascending           '                            
     O          EADD         TYPE                                                                     
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                                         +  1 'Type of file'                                    
     O                       APFILA            +  1                                                   
     O          EADD         TYPE                                                                     
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                                         +  1 'Maintenance is'                                  
     O                       MAINT             +  1                                                   
     O          EADD         TYPE                                                                     
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                       ACCPTH            +  1                                                   
     O          EADD         BASED                                                                    
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                                         +  1 'Based on Physical file'                          
     O                       APBOF             +  1                                                   
     O          EADD         WARN                                                                     
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                                         +  1 'WARNING! File contains'                          
     O                                         +  1 'Select/Omit Statements'                          
     O          EADD         ASS2RS                                                                   
     O                       ORD#                 6                                                   
     O                       UDATE               12                                                   
     O                                           19 '*'                                               
     O                       AS2RSK