/TITLE Huvudprogram
     H NOMAIN
      /COPY CrtUsrSpcP
      /TITLE CrtUsrSpc: Create User Space for OS/400 API's
      ****************************************************************
      *
      * CrtUsrSpc: Create User Space for OS/400 API's
      *
      ****************************************************************
      *
     P  CrtUsrSpc      B                   EXPORT
      *
      * --- Procedure Interface Definition
      *
     D  CrtUsrSpc      PI             1
     D  UsrSpcName                   20
      *
      * --- Local Variables
      *
     D  ReturnCode     S              1
     D  ObjName        S             10    INZ(' ')
     D  ObjLib         S             10    INZ(' ')
     D  UserSpace      S             20    INZ(' ')
     D  ExtraAtr       S             10    INZ(' ')
     D  UserInit       S              1    INZ(' ')
     D  UserAuth       S             10    INZ('*EXCLUDE  ')
     D  UserText       S             50    INZ(' ')
     D  OS400_Cmd      S            160    INZ(' ')
     D  Cmd_Length     S             15P 5 INZ(0)
     D  True           S              1    INZ( *ON  )
     D  False          S              1    INZ( *OFF )
      *
     D BinaryField     DS
     D  UserSize               1      4B 0 INZ(50000)
      *
      * Remove "User Space"
      *
     C                   EVAL      ObjName    = %SUBST(UsrSpcName :  1 : 10 )
     C                   EVAL      ObjLib     = %SUBST(UsrSpcName : 11 : 10 )
      *
     C                   EVAL      OS400_Cmd  = 'DLTUSRSPC '                   +
     C                                          'USRSPC('                      +
     C                                          %TRIM( ObjLib  )               +
     C                                          '/'                            +
     C                                          %TRIM( ObjName )               +
     C                                          ')'
     C                   EVAL      Cmd_Length = %SIZE(OS400_Cmd)
     C                   CALL      'QCMDEXC'                            89
     C                   PARM                    OS400_Cmd
     C                   PARM                    Cmd_Length
      *
      * Create "User Space"
      *
     C                   CALL      'QUSCRTUS'
     C                   PARM                    UsrSpcName
     C                   PARM                    ExtraAtr
     C                   PARM                    UserSize
     C                   PARM                    UserInit
     C                   PARM                    UserAuth
     C                   PARM                    UserText
      *
      * ReturnCode
      *
     C                   EVAL      ReturnCode = %ERROR
     C*
     C                   RETURN    ReturnCode
      *
     P  CrtUsrSpc      E
      *
      ******************************************************************
     C/TITLE