*
      *PARMS CRTRPGMOD
      *PARMS DBGVIEW(*SOURCE)
      *
     H NoMain
     H datedit(*ymd) indent('| ') option(*nodebugio:*noxref:*srcstmt)
      *
      *=====================================================================
     D/COPY QRPGSRC,TRC012M00
      *=====================================================================
     P StartSourceDebug...
     P                 B                   Export
     D StartSourceDebug...
     D                 pi
      *
     D QteStartSourceDebug...
     D                 PR                  EXTPROC('QteStartSourceDebug')
     D  StopHandler                  20a   const
     D  ApiErr                             like(ApiErrDs)
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D StopHandler                   20a   inz('TRC004    *LIBL     ')
      *
     C                   callp     QteStartSourceDebug(StopHandler:ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('StartSourceDebug: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     P                 e
      *=====================================================================
     P EndSourceDebug...
     P                 B                   Export
     D EndSourceDebug...
     D                 pi
      *
     D QteEndSourceDebug...
     D                 PR                  EXTPROC('QteEndSourceDebug')
     D  ApiErr                             like(ApiErrDs)
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     C                   callp     QteEndSourceDebug(ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('EndSourceDebug: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     P                 e
      *=====================================================================
     P RegisterDebugView...
     P                 B                   Export
     D RegisterDebugView...
     D                 pi            10i 0
     D  PgmQlfy                      20a   const
     D  PgmType                      10a   const
     D  MdlName                      10a   const
     D  ViewNumber                   10i 0 const
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D QteRegisterDebugView...
     D                 PR                  EXTPROC('QteRegisterDebugView')
     D  ViewID                       10i 0
     D  ViewLines                    10i 0
     D  PgmLibr                      10a
     D  TimeStamp                    13a
     D  PgmQlfy                      20a   const
     D  PgmType                      10a   const
     D  MdlName                      10a   const
     D  ViewNumber                   10i 0 const
     D  ApiErr                              like(ApiErrDs)
      *
     D ViewID          s             10i 0
     D ViewLines       s             10i 0
     D PgmLibr         s             10a
     D TimeStamp       s             13a
      *
     C                   callp     QteRegisterDebugView(
     C                               ViewID            :
     C                               ViewLines         :
     C                               PgmLibr           :
     C                               TimeStamp         :
     C                               PgmQlfy           :
     C                               PgmType           :
     C                               MdlName           :
     C                               ViewNumber        :
     c                               ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('RegisterDebugView: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     C                   Return    ViewID
      *
     P                 e
      *=====================================================================
     P SubmitDebugCommand...
     P                 b                   Export
     D SubmitDebugCommand...
     D                 pi
     D  ViewID                       10i 0 const
     D  CompilerID                   20a   const
     D  InpBfrDta                   128a
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D QteSubmitDebugCommand...
     D                 PR                  EXTPROC('QteSubmitDebugCommand')
     D  RcvrDta                     128
     D  RcvrSiz                      10i 0 const
     D  ViewID                       10i 0 const
     D  InpBfrDta                   128a
     D  InpBfrSiz                    10i 0
     D  CompilerID                   20a   const
     D  ApiErr                             like(ApiErrDs)
      *
     D RcvrDta         s           4096
     D RcvrSiz         s             10i 0 inz(%size(RcvrDta))
      *
     D  InpBfrSiz      s             10i 0 inz(%size(InpBfrDta))
      *
     C                   callp     QteSubmitDebugCommand(
     C                               RcvrDta           :
     C                               RcvrSiz           :
     C                               ViewID            :
     C                               InpBfrDta         :
     C                               InpBfrSiz         :
     C                               CompilerID        :
     c                               ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('SubmitDebugCommand: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     P                 e
      *=====================================================================
     P Step            b                   Export
     D Step            pi
     D  ViewID                       10i 0 const
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D QteStep         PR                  EXTPROC('QteStep')
     D  ViewID                       10i 0 const
     D  StepCount                    10i 0 const
     D  StepType                     10a   const
     D  ApiErr                              like(ApiErrDs)
      *
     C                   callp     QteStep(ViewID : 1 : '*INTO' :
     C                               ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('Step: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     P                 e
      *=====================================================================
     P GetViewInfo...
     P                 b                   Export
     D GetViewInfo...
     D                 pi            10i 0
     D  PgmQlfy                      20a   const
     D  PgmType                      10a   const
     D  MdlName                      10a   const
     D  Search                       50a   const
      *
     D RcvrDta         s           1024
      *
     D Index           s             10i 0
      *
     D Ptr001          s               *
     D RcvVar1         ds                  based(Ptr001)
     D                               10i 0
     D                               10i 0
     D Elements                      10i 0
      *
     D Ptr002          s               *
     D RcvVar2         ds                  based(Ptr002)
     D                               10a
     D ViewType                      10a
     D CompilerID                    20a
     D                               10a
     D                               13a
     D ViewDesc                      50a
     D                                3a
     D ViewNumber                    10i 0
     D                               10i 0
      *
     C                   Eval      RcvrDta = RetrieveModuleViews(
     C                               PgmQlfy  :
     C                               PgmType  :
     C                               MdlName  )
      *
     C                   Eval      Ptr001 = %addr(RcvrDta)
      *
     C                   Eval      Ptr002 = Ptr001 + %size(RcvVar1)
      *
      * Look for the required view
 B01 C                   For       Index = 1 to Elements
  01  *
 B02 C                   if        %trim(ViewDesc) = %trim(Search)
  02 C                   Return    ViewNumber
  02 C                   Leave
 E02 C                   EndIf
  01  *
  01 C                   Eval      Ptr002 = Ptr002 + %size(RcvVar2)
  01  *
 E01 C                   EndFor
      *
     C                   callp     MessageBox('GetViewInfo: ' +
     C                               %trim(Search) + ' Not found in ' +
     C                               RcvrDta)
      *
     C                   Return    -1
      *
     P                 e
      *=====================================================================
     P RetrieveModuleViews...
     P                 b                   Export
     D RetrieveModuleViews...
     D                 pi          1024
     D  PgmQlfy                      20a   const
     D  PgmType                      10a   const
     D  MdlName                      10a   const
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D QteRetrieveModuleViews...
     D                 PR                  EXTPROC('QteRetrieveModuleViews')
     D  RcvrDta                    1024
     D  RcvrSiz                      10i 0 const
     D  RcvrFmt                       8a   const
     D  PgmQlfy                      20a   const
     D  PgmType                      10a   const
     D  MdlName                      10a   const
     D  PgmLibr                      10a
     D  ApiErr                              like(ApiErrDs)
      *
     D RcvrDta         s           1024
     D RcvrSiz         s             10i 0 inz(%size(RcvrDta))
      *
     D PgmLibr         s             10a
      *
     C                   callp     QteRetrieveModuleViews(
     C                               RcvrDta              :
     C                               RcvrSiz              :
     C                               'VEWL0100'           :
     C                               PgmQlfy              :
     C                               PgmType              :
     C                               MdlName              :
     C                               PgmLibr              :
     c                               ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('RetrieveModuleViews: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
  01 C                   Return    *blanks
 E01 C                   EndIf
      *
     C                   Return    RcvrDta
      *
     P                 e
      *=====================================================================
     P MapViewPosition...
     P                 b                   Export
     D MapViewPosition...
     D                 pi            10i 0
     D  FmViewID                     10i 0 const
     D  FmLine                       10i 0 const
     D  ToViewID                     10i 0 const
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D QteMapViewPosition...
     D                 PR                  EXTPROC('QteMapViewPosition')
     D  RcvrDta                    1024
     D  RcvrSiz                      10i 0 const
     D  FmViewID                     10i 0 const
     D  FmLine                       10i 0 const
     D  Fmcolumn                     10i 0 const
     D  ToViewID                     10i 0 const
     D  ApiErr                              like(ApiErrDs)
      *
     D RcvrDta         s           1024
     D RcvrSiz         s             10i 0 inz(%size(RcvrDta))
      *
     D Ptr001          s               *   inz(%addr(RcvrDta))
     D RcvrVar1        ds                  based(Ptr001)
     D                               10i 0
     D                               10i 0
     D                               10i 0
     D  Line                         10i 0
     D  Column                       10i 0
      *
     C                   callp     QteMapViewPosition(
     C                               RcvrDta           :
     C                               RcvrSiz           :
     C                               FmViewID          :
     C                               FmLine            :
     C                               1                 :
     C                               ToViewID          :
     c                               ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('MapViewPosition: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     C                   Return    Line
      *
     P                 e
      *=====================================================================
     P RetrieveViewText...
     P                 b                   Export
     D RetrieveViewText...
     D                 pi          1024
     D  ViewID                       10i 0 const
     D  Startline                    10i 0 const
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
     D QteRetrieveViewText...
     D                 PR                  EXTPROC('QteRetrieveViewText')
     D  RcvrDta                    1024
     D  RcvrSiz                      10i 0 const
     D  ViewID                       10i 0 const
     D  Startline                    10i 0 const
     D  TotalLines                   10i 0 const
     D  LineLength                   10i 0 const
     D  ApiErr                              like(ApiErrDs)
      *
     D RcvrDta         s           1024
     D RcvrSiz         s             10i 0 inz(%size(RcvrDta))
      *
     C                   callp     QteRetrieveViewText(
     C                               RcvrDta           :
     C                               RcvrSiz           :
     C                               ViewID            :
     C                               Startline         :
     C                               1                 :
     C                               255               :
     c                               ApiErrDs)
      *
 B01 C                   if        EXMSID <> *blanks
  01 C                   callp     MessageBox('RetrieveViewText: ' +
  01 C                               EXMSID + ' ' + EXMDTA )
 E01 C                   EndIf
      *
     C                   Return    RcvrDta
      *
     P                 e
      *=====================================================================
     P MessageBox      b                   Export
     D MessageBox      pi
     D  MessageTxt                 4096a   const
      *
     D ApiErrDs      e ds                  extname(gedds99) inz
     D  exmbpr       e                     inz(%len(ApiErrDs))
      *
      * Display Long Text
     D QUILNGTX        pr                  extpgm('QUILNGTX')
     D  MessageTxt                 4096a   const
     D  MessageLen                   10i 0 const
     D  MessageIde                    7a   const
     D  MessageFil                   20a   const
     D  ApiErr                              like(ApiErrDs)
      *
     c                   callp     QUILNGTX(
     C                               MessageTxt :
     c                               %len(MessageTxt)       :
     c                               *blank                 :
     c                               *blank                 :
     c                               ApiErrDs)
     P                 e
      *=====================================================================