Code for RPG:
  h DEBUG  OPTION(*SRCSTMT:*NODEBUGIO)

 
‚‚*---------------------------------------------------------------
-----                         
    ‚‚* Display Remote Output Queues

 
‚‚*---------------------------------------------------------------
-----                         
 

      *--------------------------------------------------------------------

      * CRTBNDRPG PGM(YourLib/RMTOUTQR) SRCFILE(YourLib/QRPGLESRC)

      * DFTACTGRP(*NO) ACTGRP(ILE)

      *--------------------------------------------------------------------

    ˜frmtoutqd  cf   e             workstn

     f                                     sfile(scnsfl:sflrrn)

 

     d  CrtUsrSpc      PR              *

     d   CrtSpcName                  20    const

 

     d RcvLen          s              9B 0 inz(2048)

     d OutqLib         s             20

     d ListFormat      s              8

     d ObjNamLIb       s             20    inz('*ALL      *ALL     ')

     d ObjType         s             10    inz('*OUTQ     ')

     d SpacePtr        s               *

     d UserSpace       s             20    inz('DSPRMTOUT QTEMP')

     d sflrrn          s              5  0

 

      *--------------------------------------------------------------------

      * General Header Data structure as copied from QUSGEN in

      * source file QRPGLESRC in library QSYSINC

      *--------------------------------------------------------------------

     dQUSH0300         DS                  Based(GenDsPoint)

     d*                                             Qus Generic Header 0300

     d QUSUA00                 1     64

     d*                                             User Area

     d QUSSGH00               65     68B 0

     d*                                             Size Generic Header

     d QUSSRL00               69     72

     d*                                             Structure Release Level

     d QUSFN00                73     80

     d*                                             Format Name

     d QUSAU00                81     90

     d*                                             Api Used

     d QUSDTC00               91    103

     d*                                             Date Time Created

     d QUSIS00               104    104

     d*                                             Information Status

     d QUSSUS00              105    108B 0

     d*                                             Size User Space

     d QUSOIP00              109    112B 0

     d*                                             Offset Input Parameter

     d QUSSIP00              113    116B 0

     d*                                             Size Input Parameter

     d QUSOHS00              117    120B 0

     d*                                             Offset Header Section

     d QUSSHS00              121    124B 0

     d*                                             Size Header Section

     d QUSOLD00              125    128B 0

     d*                                             Offset List Data

     d QUSSLD00              129    132B 0

     d*                                             Size List Data

     d QUSNBRLE00            133    136B 0

     d*                                             Number List Entries

     d QUSSEE00              137    140B 0

     d*                                             Size Each Entry

     d QUSSIDLE00            141    144B 0

     d*                                             CCSID List Ent

     d QUSCID00              145    146

     d*                                             Country ID

     d QUSLID00              147    149

     d*                                             Language ID

     d QUSSLI00              150    150

     d*                                             Subset List Indicator

     d QUSRSV1               151    192

     d*                                             Reserved 1

     d QUSEPN                193    448

     d*                                             Entry Point Name

     d QUSRSV2               449    576

     d*                                             Reserved 2

 

      *--------------------------------------------------------------------

      * Format OUSL010003 List Objects. Copied from

      * member QUSLOBJ, source file QRPGLESRC, in library QSYSINC

      *--------------------------------------------------------------------

     dQUSL010003       DS                  Based(ListPoint)

     d*                                             Qus OBJL0100

     d QUSOBJNU                1     10

     d*                                             Object Name Used

     d QUSOLNU                11     20

     d*                                             Object Lib Name Used

     d QUSOBJTU               21     30

     d*                                             Object Type Used

 

      *--------------------------------------------------------------------

      * Format OUTQ0100 List Objects. Copied from

      * member QSPROUTQ, source file QRPGLESRC, in library QSYSINC

      *--------------------------------------------------------------------

     dQSPQ0100         DS

     d*                                             Qsp OUTQ0100

     d QSPBR                   1      4B 0

     d*                                             Bytes Return

     d QSPBA                   5      8B 0

     d*                                             Bytes Avail

     d QSPOQN                  9     18

     d*                                             Output Queue Name

     d QSPOQL                 19     28

     d*                                             Output Queue Lib

     d QSPOOF                 29     38

     d*                                             Order of Files

     d QSPDAFIL               39     48

     d*                                             Display Any File

     d QSPJS                  49     52B 0

     d*                                             Job Separators

     d QSPOC                  53     62

     d*                                             Operator Control

     d QSPDQN                 63     72

     d*                                             Data Queue Name

     d QSPDQL                 73     82

     d*                                             Data Queue Lib

     d QSPATC                 83     92

     d*                                             Authority to Check

     d QSPNBROF               93     96B 0

     d*                                             Number of Files

     d QSPOQS                 97    106

     d*                                             Output Queue Status

     d QSPWJN                107    116

     d*                                             Writer Job Name

     d QSPWJU                117    126

     d*                                             Writer Job User

     d QSPWJNBR              127    132

     d*                                             Writer Job Number

     d QSPWS                 133    142

     d*                                             Writer Status

     d QSPPDN                143    152

     d*                                             Printer Device Name

     d QSPOQD                153    202

     d*                                             Output Queue Descr

     d QSPRSV2               203    204

     d*                                             Reserved2

     d QSPNOPSG              205    208B 0

     d*                                             Number Of Page Sizes
Given                      
     d QSPNOWS               209    212B 0

     d*                                             Number Of Writers
Started                       
     d QSPWTA                213    216B 0

     d*                                             Writers To Autostart

     d QSPRSNT               217    217

     d*                                             Remote System Name Type

     d QSPRSN                218    472

     d*                                             Remote System Name

     d QSPRPQ                473    600

     d*                                             Remote Printer Queue

     d QSPMQ                 601    610

     d*                                             Message Queue

     d QSPMQLIB              611    620

     d*                                             Message Queue Library

     d QSPCT                 621    624B 0

     d*                                             Connection Type

     d QSPDT                 625    628B 0

     d*                                             Destination Type

     d QSPMMVSC              629    629

     d*                                             VMMVS Class

     d QSPFCB                630    637

     d*                                             FCB

     d QSPASCII              638    638

     d*                                             Transform SCS To ASCII

     d QSPMTM                639    655

     d*                                             Manufacturer Type Model

     d QSPWCO                656    665

     d*                                             Workstation Cust Obj

     d QSPWCOL               666    675

     d*                                             Workstation Cust Obj
Library                    
     d QSPSASP               676    676

     d*                                             Splf Aux Storage Pool

     d QSPSFSO               677    680B 0

     d*                                             Spooled File Size Offset

     d QSPNOSE               681    684B 0

     d*                                             Number Of Size Entries

     d QSPLOESE              685    688B 0

     d*                                             Length Of Each Size
Entry                       
     d QSPDO                 689    816

     d*                                             Destination Options

     d QSPWT                 817    817

     d*                                             Writer Type

     d QSPSP                 818    818

     d*                                             Separator Page

     d QSPLRPQ               819   1073

     d*                                             Long Remote Printer
Queue                       
     d QSPICN               1074   1083

     d*                                             Image Configuration Name

     d QSPICLIB             1084   1093

     d*                                             Image Configuration
Library                     
     d QSPNDPS              1094   1094

     d*                                             Network Directory Pub
Status                    
     d QSPRSV300            1095   1096

     d*                                             Reserved3

     d QSPASPID             1097   1100B 0

     d*                                             Aux Storage Pool ID

 

      *--------------------------------------------------------------------

      * Standard Error Code data structure

      *--------------------------------------------------------------------

     dQUSEC            DS           116

     d QUSBPRV                 1      4B 0          inz(116)

     d QUSBAVL                 5      8B 0

 

      *--------------------------------------------------------------------

      * Receiver structure to determine correct size for variable

      *--------------------------------------------------------------------

     d Receiver1       DS

     d  BytesRtn1                    10i 0

     d  BytesAvl1                    10i 0

 

      *--------------------------------------------------------------------

      *  Clear Subfile

      *--------------------------------------------------------------------

     c                   eval      *in93 = *on

     c                   write     scnctl

     c                   eval      *in93 = *off

     c                   eval      *in95 = *on

     c                   eval      sflrrn = 0

 

      *--------------------------------------------------------------------

      *  Create user space for Object List information

      *--------------------------------------------------------------------

     c                   Eval      SpacePtr = CrtUsrSpc(UserSpace)

 

      *--------------------------------------------------------------------

      *  List Objects to user space

      *--------------------------------------------------------------------

     c                   Call      'QUSLOBJ'

     c                   Parm                    UserSpace

     c                   Parm      'OBJL0100'    ListFormat

     c                   Parm                    ObjNamLib

     c                   Parm                    ObjType

     c                   Parm                    QusEc

 

      *--------------------------------------------------------------------

      *  Load the general data structure

      *--------------------------------------------------------------------

     c                   Eval      GenDsPoint = SpacePtr

 

      *  If the list API was complete or partially complete

     c                   if        QuSIS00 = 'C' OR

     c                             QuSIS00 = 'P'

 

      *  Load the list data structure

     c                   Eval      ListPoint = GenDsPoint + QusOLD00

 

b01  c                   Do        QusNbrLE00

 

     c                   movel     QUSOBJNU      OutqLib

     c                   move      QUSOLNU       OutqLib

 

      *--------------------------------------------------------------------

      *  Retrieve Outque Information

      *--------------------------------------------------------------------

     c                   Call      'QSPROUTQ'

     c                   Parm                    QSPQ0100

     c                   Parm                    RcvLen

     c                   Parm      'OUTQ0100'    ListFormat

     c                   Parm                    OutqLib

     c                   Parm                    QusEc

 

      *--------------------------------------------------------------------

      *  Write Subfile Record if Remote System

      *--------------------------------------------------------------------

     c                   if        qsprsn <> *blanks

     c                   eval      @outq  = qspoqn

     c                   eval      @sts   = qspws

     c                   eval      @txt   = qspoqd

     c                   eval      @sysn  = qsprsn

     c                   add       1             sflrrn

     c                   write     scnsfl

     c                   endif

 

     c                   Eval      ListPoint = ListPoint + QusSEE00

 

e01  c                   EndDo

     c                   Endif

 

      *--------------------------------------------------------------------

      *  Set Up Subfile Control

      *--------------------------------------------------------------------

     c                   if        sflrrn = 0

     c                   eval      *in91 = *on

     c                   else

     c                   eval      *in94 = *on

     c                   eval      *in90 = *on

     c                   eval      *in91 = *on

     c                   endif

 

      *--------------------------------------------------------------------

      *  Display Workstation Screen

      *--------------------------------------------------------------------

     c                   dow       *inkl = *off

     c                             and *inkc = *off

 

     c                   write     scnftr

     c                   exfmt     scnctl

 

     c                   enddo

 

      *--------------------------------------------------------------------

      *  End Program

      *--------------------------------------------------------------------

     c                   eval      *inlr = *on

 

      *====================================================================

      *  Procedure to create extendable user space, return pointer to it.

      *====================================================================

     p  CrtUsrSpc      B                   export

     d  CrtUsrSpc      PI              *

     d   CrtSpcName                  20    const

 

      * Local Variables

     d PasSpcName      DS            20

     d  SLib                  11     20

     d ChgAttrDs       DS            13

     d  NumberAttr                    9B 0 inz(1)

     d  KeyAttr                       9B 0 inz(3)

     d  DataSize                      9B 0 inz(1)

     d  AttrData                      1    inz('1')

     d ListPtr         S               *

     d SpaceAttr       S             10    inz

     d SpaceAuth       S             10    INZ('*CHANGE')

     d SpaceLen        S              9B 0 INZ(2048)

     d SpaceReplc      S             10    INZ('*YES')

     d SpaceText       S             50

     d SpaceValue      S              1

 

      * Create the user space

     c                   move      CrtSpcName    PasSpcName

     c                   CALL      'QUSCRTUS'

     c                   PARM                    PasSpcName

     c                   PARM                    SpaceAttr

     c                   PARM                    SpaceLen

     c                   PARM                    SpaceValue

     c                   PARM                    SpaceAuth

     c                   PARM                    SpaceText

     c                   PARM      '*YES'        SpaceReplc

     c                   PARM                    QusEc

 

      * Get pointer to user space

     c                   CALL      'QUSPTRUS'

     c                   PARM                    PasSpcName

     c                   PARM                    ListPtr

 

      * Change user space to be extendable

     c                   CALL      'QUSCUSAT'

     c                   PARM                    Slib

     c                   PARM                    PasSpcName

     c                   PARM                    ChgAttrDs

     c                   PARM                    QusEc

 

     c                   return    ListPtr

 

     p  CrtUsrSpc      E                                

code for dspf:

     A*%%TS  SD  20031217  155249  RICHQSEC    REL-V5R1M0  5722-WDS

     A*%%EC

     A                                      DSPSIZ(24 80 *DS3)

     A                                      PRINT

     A*----------------------------------------------------------------

     A          R SCNSFL                    SFL

     A*%%TS  SD  20031217  155249  RICHQSEC    REL-V5R1M0  5722-WDS

     A  95                                  SFLNXTCHG

     A            @OUTQ         10A  O  6  3

     A            @TXT          36A  O  6 14

     A            @STS           3A  O  6 51

     A            @SYSN         24A  O  6 55

     A*----------------------------------------------------------------

     A          R SCNCTL                    SFLCTL(SCNSFL)

     A*%%TS  SD  20031217  155249  RICHQSEC    REL-V5R1M0  5722-WDS

     A                                      SFLSIZ(0200)

     A                                      SFLPAG(0015)

     A                                      CF03(03 'EXIT')

     A                                      CF12(12 'CANCEL')

     A                                      OVERLAY

     A                                      SFLCSRRRN(&CURRRN)

     A  90                                  SFLDSP

     A  91                                  SFLDSPCTL

     A  92                                  SFLDLT

     A  93                                  SFLCLR

     A  94                                  SFLEND(*MORE)

     A            CURRRN         5S 0H

     A                                  1  3DATE

     A                                      EDTCDE(Y)

     A                                  1 12TIME

     A                                  1 27'Display Remote Output Queues'

     A                                      DSPATR(HI)

     A                                  1 62SYSNAME

     A                                  5  3'Output Que'

     A                                      DSPATR(HI)

     A                                      DSPATR(UL)

     A                                  5 14'Description
-
     A                                        '

     A                                      DSPATR(HI)

     A                                      DSPATR(UL)

     A                                  5 51'Sts'

     A                                      DSPATR(HI)

     A                                      DSPATR(UL)

     A                                  5 55'Remote System Name      '

     A                                      DSPATR(HI)

     A                                      DSPATR(UL)

     A          R SCNFTR

     A*%%TS  SD  20031216  134503  RICHQSEC    REL-V5R1M0  5722-WDS

     A                                 23  3'F3=Exit'

     A                                      COLOR(BLU)

     A                                 23 52'F12=Cancel'

     A                                      COLOR(BLU)


Code for Command:
/*-------------------------------------------------------------------*/

/* COMMAND.....: DSPRMTOUTQ                                          */

/* DESCRIPTION.: DISPLAY REMOTE OUTPUT QUEUES                        */

/* COMPILE.....: CRTCMD CMD(YourLib/DSPRMTOUTQ) PGM(YourLib/RMTOUTQR)  */

/*                  SRCFILE(YourLib/QCMDSRC)                          */

/*-------------------------------------------------------------------*/

             CMD        PROMPT('Display Remote Outques')